Considering Alternative Explanations for the Associations Among Childhood Adversity, Childhood Abuse, and Adult Sexual Orientation: Reply to Bailey and Bailey (2013) and Rind (2013)

Appendix: Details of the Simulations

To investigate the causal structure proposed by Bailey and Bailey, we looked at the case of same-sex identity in men, with stepparent before age 5 as the instrument, as stepparent before age 5 was least likely to be affected by reporting bias. Because most of the statistical mediation found in our data was by childhood sexual abuse, we examined sexual abuse as the mediator. We used existing genetic studies to estimate the likely effect sizes of a given single-nucleotide polymorphism (SNP) on a behavioral outcome. Evidence from genome-wide association studies (GWAS) of anthropometric measures, diseases, and behavioral traits indicate that a given SNP typically accounts for less than 0.5 % of the variation in a trait (Vrieze, Iacono, & McGue, 2012). A recent GWAS meta-analysis suggested that SNPs that affect personality have small or very small effect sizes. This study examined 2.5 million SNPs from more than 17,000 persons and failed to identified even one SNP with GWAS-level significance for neuroticism; effect sizes for SNPs associated with openness and conscientiousness were small and not well replicated (de Moor et al., 2010).

We simulated data from 15,000 individuals (in StataIC 11), using assumptions that would produce the largest confounding by gene while still being somewhat plausible given current understandings of genetics. Although we consider many of the assumptions below unlikely, assumptions that we considered likely clearly would not support Bailey and Bailey’s hypothesis. Our goal with this simulation was to assess whether even these very extreme assumptions would be consistent with Bailey and Bailey’s hypothesis:

• We assumed that mother’s neuroticism followed a normal distribution.

• We randomly assigned a neuroticism risk allele to the mother with a minor allele frequency (MAF) of 0.2. We assumed the allele increased neuroticism by 0.48 SDs (the maximum effect size found in the GWAS meta-analysis of all personality traits). We note that this combination of effect size and MAF resulted in 3.8 % of the mother’s neuroticism being accounted for by this SNP, 7 times greater than 0.5 % estimated for a typical SNP (Vrieze, Iacono, & McGue, 2012).

• We assumed that mother’s neuroticism accounted for 25 % of the probability of her child having a stepparent by age 5 (likely to be an overestimation of this effect). We coded individuals with the highest probability of having a stepparent as having a stepparent so that the prevalence of having a stepparent by age 5 was 2.6 %, as in the NESARC dataset.

• If the mother had the neuroticism risk allele, we assigned the risk allele to the child with a 0.5 probability.

• We assumed the child’s risk allele for neuroticism increased his probability of having a same-sex identity by 0.48 SDs (the maximum effect size found in the GWAS meta-analysis of all personality traits). We assigned same-sex orientation to men with the highest probability of having a same-sex orientation such that the prevalence was 1.9 %, as in the NESARC data. In the resulting dataset, the SNP explained 3 % of the child’s likelihood of having a same-sex orientation, which would be an exceptionally large effect. In the only large population-representative twin study of sexual orientation, genetic effects in total were estimated to explain .34–.39 of the variance in male sexual orientation (Langstrom, Rahman, Carlstrom, & Lichtenstein, 2010). Thus, the neuroticism SNP would explain 8 % of the genetic component of same-sex orientation. This approach also assumes that the gene has the same effect size on neuroticism and sexual orientation, which is highly unlikely.

Using data resulting from this simulation, we fit a model for same-sex orientation using stepparent as the predictor. The odds ratio (OR) for stepparent in this model was 1.07 (95 % confidence interval [CI] = 0.5, 2.2). In contrast, in the NESARC data having a stepparent was a strong predictor of sexual orientation (OR = 1.8, 95 % CI = 1.2, 2.7).

Since our initial assumptions did not produce the associations found in the NESARC data, we further explored the assumptions required to produce those associations. We assumed that the SNP had an effect size of 1 (presence of the risk allele increased the mother’s neuroticism by 1 SD, which resulted in the gene accounting for 14 % of mother’s neuroticism). These assumptions resulted in mother’s neuroticism accounting for 38 % of the likelihood of having a stepparent before age 5. It seems very unlikely that neuroticism (or any other genetic factor) could account for more than one-third of the risk of divorce or death of spouse and remarriage by the child’s age 5. Nonetheless, these assumptions still did not create an association between same-sex sexuality and having a stepparent as large as that in the NESARC data (OR = 1.4, 95 % CI = 0.7, 2.6). To obtain an association similar to that found in NESARC, we assumed the mother’s neuroticism increased likelihood of having a stepparent by 1.35 SD, resulting in her neuroticism accounting for 50 % of the likelihood of having a stepparent, a very implausible scenario.

We then turned to the issue of statistical mediation by childhood sexual abuse. We assumed that the child’s underlying risk of sexual abuse (a continuous variable) was a function of mother’s neuroticism, such that mother’s neuroticism increased risk by 0.3 SD and the child’s risk gene increased risk by 0.48 SD (following Bailey and Bailey’s hypothesis that the child’s gene would affect the child’s experience of sexual abuse more strongly than the mother’s neuroticism). With these somewhat arbitrary assumptions, mother’s neuroticism accounted for 10 % of the child’s risk of sexual abuse and the child’s neuroticism risk allele accounted for 5 % of the child’s risk of sexual abuse (an exceptionally large, and unlikely, effect size).

We assigned sexual abuse as high, medium, low or none based on risk of abuse to match the prevalence of sexual abuse in NESARC, irrespective of sexual identity. With this assumption, the prevalence of moderate and high levels of sexual abuse in gay men were substantially lower than these prevalences in NESARC and sexual abuse did not mediate the association between stepparent and likelihood of being gay. We therefore next assumed that the child’s nascent sexual identity affected risk of abuse. We assigned sexual abuse as high, medium, low or none according to risk of abuse to match the prevalence of abuse among persons with and without same-sex identity in the NESARC data. We then calculated ORs for same-sex identity as the dependent variable with having a stepparent before age 5 and sexual abuse (high, medium, low or none) as the independent variable. In this model, the association of stepparent with same-sex identity was attenuated from the model without sexual abuse (adjusted model, OR = 1.2, 95 % CI = 0.6, 2.2; unadjusted model OR = 1.7, 95 % CI = 0.9, 3.0). These results were similar to those obtained using the NESARC data.

STATA code

*15000 observations

clear

set obs 15000

*minor allele frequency=0.2

set seed 2829382

*does the mother have the allele?

gen gene=uniform()>.8

*gene increases neuroticism by .48 standardized beta

*(maximum effect from Big 5 genetic study)

gen momneurotic=invnorm(uniform())+(.48*gene)

reg momneurotic gene

*gene accounts for 3.8% of mother’s neuroticism

*producing a prevalence of 2.6% of people with stepparent before age 5

*makes mom’s neuroticism account for 25% of the probability of having a stepparent

gen stepparent=(0.8*momneurotic+invnorm(uniform()))>2.62

sum

*does the child inherit the allele from the father?

set seed 1462964

gen childhasgene=uniform()>.9

*does the child inherit the allele from the mother?

gen coinflip=uniform()>.5 if gene=1

replace childhasgene=gene if coinflip=1

tab gene childhasgene, r col

*child’s orientation: 0.019 of men are gay in NESARC, use maximum effect from Big 5 study

gen childgay=invnorm(uniform())+(0.48*childhasgene)>2.2

*with these assumptions, the neuroticism gene accounts for 3.3% of the child’s likelihood of being gay

logit childgay childhasgene

*does this set of assumptions produce an association between child’s orientation and stepparent that we see in the data? (no, no association)

sum

tab childgay stepparent, chi2 column exact row

*does it produce an OR=1.8, as we see in the data? (no, OR=1.07)

logit childgay stepparent, or

*what if the gene increases neurotic by 1 SD and childgay by 1 SD instead?

gen momneurotic1=invnorm(uniform())+(1*gene)

*producing a prevalence of 2.6% of people with stepparent before age 5

gen stepparent1=(0.8*momneurotic1+invnorm(uniform()))>2.75

sum

*mother’s neuroticism now accounts for 29% of the probability of having a stepparent before age 5

logit stepparent1 momneurotic1

*child’s orientation: 0.019 of men are gay in NESARC

*using 1 SD effect of the gene on orientation

gen childgay1=invnorm(uniform())+(1*childhasgene)>2.47

tab childgay1

*the gene now accounts for 14.6% of the probability of the child being gay

logit childgay1 childhasgene

*does this set of assumptions produce an association between child’s orientation and

*stepparent that we see in our data? (no, OR=0.9)

tab childgay1 stepparent1, chi2 column exact row

logit childgay1 stepparent1, or

*what if mother’s neuroticism accounts for a larger portion of likelihood of having a stepparent?

gen stepparent2=(momneurotic1+invnorm(uniform()))>3.05

sum

*mother’s neuroticism now accounts for 36% of the probability of having a stepparent<age 5

logit stepparent2 momneurotic1

*does this produce the association between child sexual identity and stepparent in NESARC?

*No, OR=1.4

tab childgay1 stepparent2, chi2 column exact row

logit childgay1 stepparent2, or

*what if mother’s neuroticism accounts for an even larger portion of likelihood of stepparent?

gen stepparent3=(1.35*momneurotic1+invnorm(uniform()))>3.75

sum

*mother’s neuroticism accounts for 50% of the likelihood of having a stepparent

logit stepparent3 momneurotic1

*does this produce the association between child sexual identity and stepparent in NESARC?

*almost, OR=1.7, 95% CI=0.9, 3.0

tab childgay1 stepparent3, chi2 column exact row

logit childgay1 stepparent3, or

*adding abuse

*abuse risk a function both of mom neuroticism and the child’s gene

gen childabuse=invnorm(uniform())+(.3*momneurotic1)+(.48*childhasgene)

*mother’s neuroticism accounts for 10% of child’s sexual abuse risk

reg childabuse momneurotic1

*child’s gene accounts for 4.7% of his risk of sexual abuse

reg childabuse childhasgene

*if childgay does not affect risk of sexual abuse in this simulation, sexual abuse among gay men

*here (low, 2.2%; medium, 3.1%, high, 3.1%) is far lower than in NESARC (low, 2.2%; medium, 4.3%, high, 7.1%)

gen sexabuse=(childabuse>2.35)+(childabuse>2.05)+(childabuse>1.85)

tab sexabuse

tab childgay1 sexabuse, r col

*and sex abuse does not attenuate the association between stepparent and gay as in NESARC

*adjusted OR=1.6, 95% CI=0.9, 2.9

egen byte sexabuse1=anycount(sexabuse), values(1)

egen byte sexabuse2=anycount(sexabuse), values(2)

egen byte sexabuse3=anycount(sexabuse), values(3)

logit childgay1 stepparent3 sexabuse1 sexabuse2 sexabuse3,or

*making sexual orientation affect sexual abuse

*prevalences in NESARC: straight men: low (1.8%), medium (1.7%), high abuse (2.0%)

*gay men: low (1.9%), medium (4.7%), high abuse (12.6%)

drop sexabuse sexabuse1 sexabuse2 sexabuse3

gen sexabuse=(childabuse>2.35)+(childabuse>2.05)+(childabuse>1.85) if childgay1==0

replace sexabuse=(childabuse>1.65)+(childabuse>1.49)+(childabuse>1.34) if childgay1==1

tab childgay1 sexabuse, r col

*does sex abuse attenuate the association between stepparent and gay as in NESARC?

*yes, adjusted OR=1.2, 95% CI=0.6, 2.2

*making indicator variables

egen byte sexabuse1=anycount(sexabuse), values(1)

egen byte sexabuse2=anycount(sexabuse), values(2)

egen byte sexabuse3=anycount(sexabuse), values(3)

logit childgay1 stepparent3 sexabuse1 sexabuse2 sexabuse3, or